home *** CD-ROM | disk | FTP | other *** search
/ Cream of the Crop 26 / Cream of the Crop 26.iso / os2 / octa209s.zip / octave-2.09 / libcruft / lapack / dgehrd.f < prev    next >
Text File  |  1996-07-19  |  8KB  |  243 lines
  1.       SUBROUTINE DGEHRD( N, ILO, IHI, A, LDA, TAU, WORK, LWORK, INFO )
  2. *
  3. *  -- LAPACK routine (version 2.0) --
  4. *     Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
  5. *     Courant Institute, Argonne National Lab, and Rice University
  6. *     September 30, 1994
  7. *
  8. *     .. Scalar Arguments ..
  9.       INTEGER            IHI, ILO, INFO, LDA, LWORK, N
  10. *     ..
  11. *     .. Array Arguments ..
  12.       DOUBLE PRECISION   A( LDA, * ), TAU( * ), WORK( LWORK )
  13. *     ..
  14. *
  15. *  Purpose
  16. *  =======
  17. *
  18. *  DGEHRD reduces a real general matrix A to upper Hessenberg form H by
  19. *  an orthogonal similarity transformation:  Q' * A * Q = H .
  20. *
  21. *  Arguments
  22. *  =========
  23. *
  24. *  N       (input) INTEGER
  25. *          The order of the matrix A.  N >= 0.
  26. *
  27. *  ILO     (input) INTEGER
  28. *  IHI     (input) INTEGER
  29. *          It is assumed that A is already upper triangular in rows
  30. *          and columns 1:ILO-1 and IHI+1:N. ILO and IHI are normally
  31. *          set by a previous call to DGEBAL; otherwise they should be
  32. *          set to 1 and N respectively. See Further Details.
  33. *          1 <= ILO <= IHI <= N, if N > 0; ILO=1 and IHI=0, if N=0.
  34. *
  35. *  A       (input/output) DOUBLE PRECISION array, dimension (LDA,N)
  36. *          On entry, the N-by-N general matrix to be reduced.
  37. *          On exit, the upper triangle and the first subdiagonal of A
  38. *          are overwritten with the upper Hessenberg matrix H, and the
  39. *          elements below the first subdiagonal, with the array TAU,
  40. *          represent the orthogonal matrix Q as a product of elementary
  41. *          reflectors. See Further Details.
  42. *
  43. *  LDA     (input) INTEGER
  44. *          The leading dimension of the array A.  LDA >= max(1,N).
  45. *
  46. *  TAU     (output) DOUBLE PRECISION array, dimension (N-1)
  47. *          The scalar factors of the elementary reflectors (see Further
  48. *          Details). Elements 1:ILO-1 and IHI:N-1 of TAU are set to
  49. *          zero.
  50. *
  51. *  WORK    (workspace/output) DOUBLE PRECISION array, dimension (LWORK)
  52. *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
  53. *
  54. *  LWORK   (input) INTEGER
  55. *          The length of the array WORK.  LWORK >= max(1,N).
  56. *          For optimum performance LWORK >= N*NB, where NB is the
  57. *          optimal blocksize.
  58. *
  59. *  INFO    (output) INTEGER
  60. *          = 0:  successful exit
  61. *          < 0:  if INFO = -i, the i-th argument had an illegal value.
  62. *
  63. *  Further Details
  64. *  ===============
  65. *
  66. *  The matrix Q is represented as a product of (ihi-ilo) elementary
  67. *  reflectors
  68. *
  69. *     Q = H(ilo) H(ilo+1) . . . H(ihi-1).
  70. *
  71. *  Each H(i) has the form
  72. *
  73. *     H(i) = I - tau * v * v'
  74. *
  75. *  where tau is a real scalar, and v is a real vector with
  76. *  v(1:i) = 0, v(i+1) = 1 and v(ihi+1:n) = 0; v(i+2:ihi) is stored on
  77. *  exit in A(i+2:ihi,i), and tau in TAU(i).
  78. *
  79. *  The contents of A are illustrated by the following example, with
  80. *  n = 7, ilo = 2 and ihi = 6:
  81. *
  82. *  on entry,                        on exit,
  83. *
  84. *  ( a   a   a   a   a   a   a )    (  a   a   h   h   h   h   a )
  85. *  (     a   a   a   a   a   a )    (      a   h   h   h   h   a )
  86. *  (     a   a   a   a   a   a )    (      h   h   h   h   h   h )
  87. *  (     a   a   a   a   a   a )    (      v2  h   h   h   h   h )
  88. *  (     a   a   a   a   a   a )    (      v2  v3  h   h   h   h )
  89. *  (     a   a   a   a   a   a )    (      v2  v3  v4  h   h   h )
  90. *  (                         a )    (                          a )
  91. *
  92. *  where a denotes an element of the original matrix A, h denotes a
  93. *  modified element of the upper Hessenberg matrix H, and vi denotes an
  94. *  element of the vector defining H(i).
  95. *
  96. *  =====================================================================
  97. *
  98. *     .. Parameters ..
  99.       INTEGER            NBMAX, LDT
  100.       PARAMETER          ( NBMAX = 64, LDT = NBMAX+1 )
  101.       DOUBLE PRECISION   ZERO, ONE
  102.       PARAMETER          ( ZERO = 0.0D+0, ONE = 1.0D+0 )
  103. *     ..
  104. *     .. Local Scalars ..
  105.       INTEGER            I, IB, IINFO, IWS, LDWORK, NB, NBMIN, NH, NX
  106.       DOUBLE PRECISION   EI
  107. *     ..
  108. *     .. Local Arrays ..
  109.       DOUBLE PRECISION   T( LDT, NBMAX )
  110. *     ..
  111. *     .. External Subroutines ..
  112.       EXTERNAL           DGEHD2, DGEMM, DLAHRD, DLARFB, XERBLA
  113. *     ..
  114. *     .. Intrinsic Functions ..
  115.       INTRINSIC          MAX, MIN
  116. *     ..
  117. *     .. External Functions ..
  118.       INTEGER            ILAENV
  119.       EXTERNAL           ILAENV
  120. *     ..
  121. *     .. Executable Statements ..
  122. *
  123. *     Test the input parameters
  124. *
  125.       INFO = 0
  126.       IF( N.LT.0 ) THEN
  127.          INFO = -1
  128.       ELSE IF( ILO.LT.1 .OR. ILO.GT.MAX( 1, N ) ) THEN
  129.          INFO = -2
  130.       ELSE IF( IHI.LT.MIN( ILO, N ) .OR. IHI.GT.N ) THEN
  131.          INFO = -3
  132.       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
  133.          INFO = -5
  134.       ELSE IF( LWORK.LT.MAX( 1, N ) ) THEN
  135.          INFO = -8
  136.       END IF
  137.       IF( INFO.NE.0 ) THEN
  138.          CALL XERBLA( 'DGEHRD', -INFO )
  139.          RETURN
  140.       END IF
  141. *
  142. *     Set elements 1:ILO-1 and IHI:N-1 of TAU to zero
  143. *
  144.       DO 10 I = 1, ILO - 1
  145.          TAU( I ) = ZERO
  146.    10 CONTINUE
  147.       DO 20 I = MAX( 1, IHI ), N - 1
  148.          TAU( I ) = ZERO
  149.    20 CONTINUE
  150. *
  151. *     Quick return if possible
  152. *
  153.       NH = IHI - ILO + 1
  154.       IF( NH.LE.1 ) THEN
  155.          WORK( 1 ) = 1
  156.          RETURN
  157.       END IF
  158. *
  159. *     Determine the block size.
  160. *
  161.       NB = MIN( NBMAX, ILAENV( 1, 'DGEHRD', ' ', N, ILO, IHI, -1 ) )
  162.       NBMIN = 2
  163.       IWS = 1
  164.       IF( NB.GT.1 .AND. NB.LT.NH ) THEN
  165. *
  166. *        Determine when to cross over from blocked to unblocked code
  167. *        (last block is always handled by unblocked code).
  168. *
  169.          NX = MAX( NB, ILAENV( 3, 'DGEHRD', ' ', N, ILO, IHI, -1 ) )
  170.          IF( NX.LT.NH ) THEN
  171. *
  172. *           Determine if workspace is large enough for blocked code.
  173. *
  174.             IWS = N*NB
  175.             IF( LWORK.LT.IWS ) THEN
  176. *
  177. *              Not enough workspace to use optimal NB:  determine the
  178. *              minimum value of NB, and reduce NB or force use of
  179. *              unblocked code.
  180. *
  181.                NBMIN = MAX( 2, ILAENV( 2, 'DGEHRD', ' ', N, ILO, IHI,
  182.      $                 -1 ) )
  183.                IF( LWORK.GE.N*NBMIN ) THEN
  184.                   NB = LWORK / N
  185.                ELSE
  186.                   NB = 1
  187.                END IF
  188.             END IF
  189.          END IF
  190.       END IF
  191.       LDWORK = N
  192. *
  193.       IF( NB.LT.NBMIN .OR. NB.GE.NH ) THEN
  194. *
  195. *        Use unblocked code below
  196. *
  197.          I = ILO
  198. *
  199.       ELSE
  200. *
  201. *        Use blocked code
  202. *
  203.          DO 30 I = ILO, IHI - 1 - NX, NB
  204.             IB = MIN( NB, IHI-I )
  205. *
  206. *           Reduce columns i:i+ib-1 to Hessenberg form, returning the
  207. *           matrices V and T of the block reflector H = I - V*T*V'
  208. *           which performs the reduction, and also the matrix Y = A*V*T
  209. *
  210.             CALL DLAHRD( IHI, I, IB, A( 1, I ), LDA, TAU( I ), T, LDT,
  211.      $                   WORK, LDWORK )
  212. *
  213. *           Apply the block reflector H to A(1:ihi,i+ib:ihi) from the
  214. *           right, computing  A := A - Y * V'. V(i+ib,ib-1) must be set
  215. *           to 1.
  216. *
  217.             EI = A( I+IB, I+IB-1 )
  218.             A( I+IB, I+IB-1 ) = ONE
  219.             CALL DGEMM( 'No transpose', 'Transpose', IHI, IHI-I-IB+1,
  220.      $                  IB, -ONE, WORK, LDWORK, A( I+IB, I ), LDA, ONE,
  221.      $                  A( 1, I+IB ), LDA )
  222.             A( I+IB, I+IB-1 ) = EI
  223. *
  224. *           Apply the block reflector H to A(i+1:ihi,i+ib:n) from the
  225. *           left
  226. *
  227.             CALL DLARFB( 'Left', 'Transpose', 'Forward', 'Columnwise',
  228.      $                   IHI-I, N-I-IB+1, IB, A( I+1, I ), LDA, T, LDT,
  229.      $                   A( I+1, I+IB ), LDA, WORK, LDWORK )
  230.    30    CONTINUE
  231.       END IF
  232. *
  233. *     Use unblocked code to reduce the rest of the matrix
  234. *
  235.       CALL DGEHD2( N, I, IHI, A, LDA, TAU, WORK, IINFO )
  236.       WORK( 1 ) = IWS
  237. *
  238.       RETURN
  239. *
  240. *     End of DGEHRD
  241. *
  242.       END
  243.